home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / R-Shows / (c)sds.d64 / man sprite (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  2KB  |  67 lines
  1. 10 REM ----- SPRITE DEMO -----
  2. 15 PRINT"[147][144]"
  3. 16 POKE 53281,1
  4. 20 REM ----- SET UP -----
  5. 22 V=53248     : REM VIC CHIP START ADD
  6. 23 REM ----- PICTURE -----
  7. 24 B=200       : REM BLOCK NUMBER
  8. 26 POKE 2040,B : REM POKE BLOCK 200
  9. 28 GOSUB 200   : REM STORE PICTURE
  10. 30 REM ----- ENABLE SPRITE 0 -----
  11. 32 POKE V+21,1 : REM TURN ON SPRITE 0
  12. 34 POKE V+39,0 : REM COLOUR IT BLACK
  13. 40 REM ----- USE TO SPRITE -----
  14. 42 FOR P=1 TO 200
  15. 44 POKE V+0,P  : REM X POSITION
  16. 45 POKE V+1,P  : REM Y POSITION
  17. 49 NEXT P
  18. 50 FOR I = 7 TO 0 STEP -1
  19. 55 POKE V+39,I : REM ALL COLOURS
  20. 60 FOR T =1 TO 1000: NEXT T
  21. 65 NEXT I
  22. 70 POKE V+29,1 : REM FAT SPRITE
  23. 71 GOSUB 100
  24. 72 POKE V+23,1 : REM FAT AND TALL
  25. 73 GOSUB 100
  26. 74 POKE V+29,0 : REM TALL ONLY
  27. 75 GOSUB 100
  28. 76 POKE V+23,0 : REM SMALL AGAIN
  29. 77 GOSUB 100
  30. 90 POKE V+21,0 : REM TURN SPRITE OFF
  31. 96 LIST 300-
  32. 100 FOR T=1 TO 1000:NEXT T: RETURN
  33. 200 REM ----- STORY SPRITE -----
  34. 201 L=0:PRINT"PLEASE WAIT"
  35. 202 FOR I = 0 TO 20: READ R$
  36. 206 FOR J=0 TO 2:S$=MID$(R$,J*8+2,8)
  37. 210 N=0:P=128
  38. 215 FOR K=1 TO 8:D$=MID$(S$,K,1)
  39. 220 IF D$="*"THEN N=N+P
  40. 225 P=P/2:NEXT K
  41. 230 POKE B*64+L,N:L=L+1
  42. 280 NEXT J,I:PRINT"[147]"
  43. 299 RETURN
  44. 300 REM  ------------------------
  45. 301 DATA!         ****           !
  46. 302 DATA!         *  *           !
  47. 303 DATA!        **  **    **    !
  48. 304 DATA!        **  **   ***    !
  49. 305 DATA!         *  *    ***    !
  50. 306 DATA!         ****     *     !
  51. 307 DATA!          **      *     !
  52. 308 DATA!          **      *     !
  53. 309 DATA!    ***************     !
  54. 310 DATA!    *   ******          !
  55. 311 DATA!    *   ******          !
  56. 312 DATA!    *    ****           !
  57. 313 DATA!   ***   ****           !
  58. 314 DATA!   ***    **            !
  59. 315 DATA!   **     **            !
  60. 316 DATA!         ****           !
  61. 317 DATA!         ****           !
  62. 318 DATA!         *  *           !
  63. 319 DATA!         *  *           !
  64. 320 DATA!     *****  *****       !
  65. 321 DATA!     *****  *****       !
  66. 322 REM  ------------------------
  67.